การแปลงตัวเลขเป็นค่าเงินภาษาอังกฤษ English Text

วิธีการแปลงยอดรวมตัวเลขเป็นค่าเงินภาษาอังกฤษ (English Text)ใน Excel

ด้วยการสร้างฟังก์ชัน Called SpellNumber และนำมาใช้เป็น Add-In ใน Microsoft Excel ซึ่ง Add-In - Called SpellNumber ไม่ใช่ฟังก์ชันดั้งเดิมของ MS Excel จึงทำให้สามารถใช้ได้ต่อเมื่อได้เพิ่มฟังก์ขัน Spellnumber แล้วเท่านั้น

วิธีสร้างฟังก์ชัน SpellNumber

1. เปิด Microsoft Excel สำหรับ user ที่ไม่เคยใช้ Developer ต้องเปิด Developer ก่อนเพื่อ Enable Macro เพราะไม่เช่นนั้นจะเกิดปัญหาบันทึกโมดูลไม่ได้ ลิงก์เพื่อดูการเปิด Developer Tab


2. เข้าที่แทป Developer เลือก Macro Security ซึ่งเป็นรูปสามเหลี่ยมสีเหลืองตามภาพ
   


3. เข้า Trust Center(ด้านซ้าย) เลือกหัวข้อ Enable all macro (not recommended; potentially dangerous code can run) แล้ว ok
   


4. เมื่อกลับมาที่หน้า worksheet ให้กด ALT+F11 เพื่อเปิดใช้งาน Visual Basic Editor หรือ เลือก Developer Tab แล้วเลือก Visual Basic
   
   
   

   1. เข้าเมนู แทรก(Insert)
   2. คลิกโมดูล (Module)
   3. แล้วพิมพ์รหัสวางในโมดูล (ใช้คัดลอกได้)
   

รหัสที่ใช้คัดลอกไปวางที่โมดูลที่เพิ่มใหม่

Option Explicit
'Main Function
Function SpellNumber(ByVal MyNumber)
    Dim Dollars, Cents, Temp
    Dim DecimalPlace, Count
    ReDim Place(9) As String
    Place(2) = " Thousand "
    Place(3) = " Million "
    Place(4) = " Billion "
    Place(5) = " Trillion "
    ' String representation of amount.
    MyNumber = Trim(Str(MyNumber))
    ' Position of decimal place 0 if none.
    DecimalPlace = InStr(MyNumber, ".")
    ' Convert cents and set MyNumber to dollar amount.
    If DecimalPlace > 0 Then
        Cents = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & _
                  "00", 2))
        MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
   End If
   Count = 1
   Do While MyNumber <> ""
        Temp = GetHundreds(Right(MyNumber, 3))
        If Temp <> "" Then Dollars = Temp & Place(Count) & Dollars
        If Len(MyNumber) > 3 Then
            MyNumber = Left(MyNumber, Len(MyNumber) - 3)
        Else
            MyNumber = ""
        End If
        Count = Count + 1
    Loop
    Select Case Dollars
        Case ""
            Dollars = "No Dollars"
        Case "One"
            Dollars = "One Dollar"
         Case Else
            Dollars = Dollars & " Dollars"
    End Select
    Select Case Cents
        Case ""
            Cents = " and No Cents"
        Case "One"
            Cents = " and One Cent"
              Case Else
            Cents = " and " & Cents & " Cents"
    End Select
    SpellNumber = Dollars & Cents
End Function      
' Converts a number from 100-999 into text 
Function GetHundreds(ByVal MyNumber)
    Dim Result As String
    If Val(MyNumber) = 0 Then Exit Function
    MyNumber = Right("000" & MyNumber, 3)
    ' Convert the hundreds place.
    If Mid(MyNumber, 1, 1) <> "0" Then
        Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
    End If
    ' Convert the tens and ones place.
    If Mid(MyNumber, 2, 1) <> "0" Then
        Result = Result & GetTens(Mid(MyNumber, 2))
    Else
        Result = Result & GetDigit(Mid(MyNumber, 3))
    End If
    GetHundreds = Result
End Function      
' Converts a number from 10 to 99 into text. 
Function GetTens(TensText)
    Dim Result As String
    Result = ""           ' Null out the temporary function value.
    If Val(Left(TensText, 1)) = 1 Then   ' If value between 10-19...
        Select Case Val(TensText)
            Case 10: Result = "Ten"
            Case 11: Result = "Eleven"
            Case 12: Result = "Twelve"
            Case 13: Result = "Thirteen"
            Case 14: Result = "Fourteen"
            Case 15: Result = "Fifteen"
            Case 16: Result = "Sixteen"
            Case 17: Result = "Seventeen"
            Case 18: Result = "Eighteen"
            Case 19: Result = "Nineteen"
            Case Else
        End Select
    Else                                 ' If value between 20-99...
        Select Case Val(Left(TensText, 1))
            Case 2: Result = "Twenty "
            Case 3: Result = "Thirty "
            Case 4: Result = "Forty "
            Case 5: Result = "Fifty "
            Case 6: Result = "Sixty "
            Case 7: Result = "Seventy "
            Case 8: Result = "Eighty "
            Case 9: Result = "Ninety "
            Case Else
        End Select
        Result = Result & GetDigit _
            (Right(TensText, 1))  ' Retrieve ones place.
    End If
    GetTens = Result
End Function     
' Converts a number from 1 to 9 into text. 
Function GetDigit(Digit)
    Select Case Val(Digit)
        Case 1: GetDigit = "One"
        Case 2: GetDigit = "Two"
        Case 3: GetDigit = "Three"
        Case 4: GetDigit = "Four"
        Case 5: GetDigit = "Five"
        Case 6: GetDigit = "Six"
        Case 7: GetDigit = "Seven"
        Case 8: GetDigit = "Eight"
        Case 9: GetDigit = "Nine"
        Case Else: GetDigit = ""
    End Select
End Function 
  

5. บันทึก
   


6. File name พิมพ์ชื่อไฟล์เป็น Spellnumber และ ลือกรูปแบบ (Save as types) เป็น Excel Add-IN ซึ่ง Excel จะเลือกไปบันทึกยังโฟลเดอร์ Add-In อัตโนมัติ จากนั้น กด Save
   


7. เมื่อกลับมาที่ worksheet ให้ไปที่ office button อีกครั้งแล้วเข้า Excel options


8. เข้าหัวข้อ Add-In ทางด้านล่างของหน้า จะมีตัวเลือก Manage: Excel Add-ins ให้คลิก 
   Go....
   
   
   
   

   

---

วิธีใช้ฟังก์ชัน Spellnumber เหมือนการใช้ฟังก์ชันอื่นๆ ใน Excel

รูปแบบฟังก์ชัน = Spellnumber(number or cell)

ฟังก์ชัน Spellnumber สามารถใช้ได้ 2 รูปแบบคือ 1. ป้อนตัวเลขในฟังก์ชันเลย กับ 2. อ้างอิงไปยังเซลล์ที่ต้องการ

Row	Column
	A	B	C
1	ตัวเลข	แสดงการใช้ฟังก์ชัน	ผลลัพท์จาก Spellnumber
2	12.75	= Spellnumber(12.75)	Twelve Dollars and Seventy Five Cents
3	402.50	= Spellnumber(A3)	Four Hundred Two Dollars and Fifty Cents

credit:

http://support.microsoft.com